@winsize_set(1)
@char_on(0,ch特2.png,500,120)
@char_dsp()

さて始まりました！　シナリオ作成講座です。
ここではシナリオで使用する「コマンド」を説明します。
これを見て自作のシナリオを作ってください。
先ず、このシナリオファイル(000addsin1280.txt)をメモ帳などで開いて下さい。
場所は『\usercustom\シナリオ01シナリオ講座\sin』フォルダ下にあります。
　

@@ @stage(0シナリオ編集ボタン1.png)
@@ シナリオファイルをメモ帳等で編集する以外に、「シナリオ編集画面」で
@@ 編集する方法もあります。
@@ タイトル画面でシナリオ編集ボタンを押すと「シナリオ編集画面」に移行します。※この画像は旧Verですが、操作は同じです
@@ ここでシナリオを編集すると「コマンド挿入」を使う事が出来ます。

@@ @stage(0シナリオ編集画面1.png)
@@ 「シナリオ編集画面」でコマンド挿入したい行にカーソルを移動し、
@@ 丸印の場所でコマンド種別の選択を行い、挿入ボタンを押します。

@@ @stage(0テキスト系1.png)
@@ するとコマンド名の付いたボタンが現れます。
@@ ここで、挿入したいコマンド名のボタンを押して下さい。

@@ @stage(0テキスト色コマンド1.png)
@@ コマンドによっては、さらにパラメータの選択を行います。
@@ そして、最後に挿入ボタンを押せば、コマンドが挿入されます。
@@ シナリオ作成講座を読み終えた後で、試してみて下さい。

シナリオで使用しているコマンドについての詳細は、
「コマンド説明(0コマンド説明(ADV2).html)」も参照して下さい。

@stage(0)
ではシナリオ作成講座を行います。
メニューから項目を選んでください。


*選択1
@char_off()
@stage(0)
講座メニュー選択1
@menu_pos(200,50,800,テキスト系,画像表示系,名前系,選択系,移動系,次ページ)
@@　@menu_pos(200,50,800,テキスト系,麻雀系,画像表示系,名前系,選択系,移動系,次ページ)
@@ @menu(テキスト系,麻雀系,表示系,名前系,選択系,移動系,次ページ)
@@@@@　テキスト系
@ans(1)
@goto_label(テキスト系)
@ansend()
@@@@@　麻雀系
@@　@ans(2)
@@　@goto_label(麻雀系)
@@　@ansend()
@@@@@　表示系
@ans(2)
@goto_label(表示系)
@ansend()
@@@@@　名前系
@ans(3)
@goto_label(名前系)
@ansend()
@@@@@　選択系
@ans(4)
@goto_label(選択系)
@ansend()
@@@@@　移動系
@ans(5)
@goto_label(移動系)
@ansend()
@@@@@　次ページ
@ans(6)
@goto_label(次ページ)
@ansend()


*テキスト系
@set_chapter(テキスト系)
ここで説明するコマンドは以下の通りです。
　@key_wait_p()　：改ページ
　@text_color()　：テキスト色設定　　　　　　　　　　　　　　　　　　　　@change_font()　：メッセージフォント変更
　@memo()　：メモ表示
　@click_win()：　クリック画面
　@click_win_design()：　クリック画面デザイン
　[＠f:XX:]　：フラグ内容埋め込み表示
　[＠RSV:XX:]　：予約語埋め込み表示
　※実際のコマンドでは”@”は半角ですが、そのままではコマンドが作動してしまうので全角にしています

シナリオファイルを見ての通り、基本はテキストファイルに文章を記述すると、
それがそのまま表示されます。　ちょっと見づらいですね。
そのうえで、最初に説明したいコマンドが『@key_wait_p()』です
通常、ウィンドウ表示ではテキスト3行で1ページとなり、改ページします。
(3行目が長い場合等は表示は4行になります)
しかし、1行や2行で改ページしたい場合に使用するのが、『@key_wait_p()』　改ページコマンドです。
試しに、改ページをして見ましょう。
@key_wait_p()
ちゃんと改ページできたでしょうか？
「@key_wait_p()」を文章の改ページしたい所に記述してください。
ちなみに、@(半角アットマーク)が行の先頭に無いとコマンドを認識しないので気をつけて下さい。
@key_wait_p()
ついでに『改行』と『コメント』も説明しましょう。
何も記述の無い改行だけの行は、シナリオでは無視されます。




@key_wait_p()
行の先頭から『@』を2個以上重ねるとコメント行になります。
以下に例文を示します。(シナリオファイルを参照して下さい)
@key_wait_p()


@@@@@@@@@@@@@@@@@@@
@@　コメント行です
@@　コメント行です
@@@@@@@@@@@@@@@@@@@

@key_wait_p()
どうでしょう？　コメントは飛ばして表示されましたね。
コメント行は表示されませんので、シナリオを見易くするのに
使って下さい。

@key_wait_p()
　@text_color(P1)：テキスト色設定
　P1：色指定
パラメータに設定した「色」にテキスト色が変化します。

色指定には、2パターンの指定方法が有ります。
　(1)文字指定　"white"，"RED"など色の英単語を記述する方法です。
　(2)カラーコード指定　RGBコードです。　赤の場合→#FF0000

※色指定の詳細はコマンドマニュアルを参照して下さい

@key_wait_p()
試しに「赤」にして見ましょう。
記述→@text_color(RED)

@key_wait_p()
@text_color(RED)
赤になりましたか？
今度は青(カラーコード)にして見ます。
記述→@text_color(#0000FF)

@key_wait_p()
@text_color(#0000FF)
青ですね。
このコマンドを使うと以降のメッセージ色が変わります。
　では白に戻して、次のコマンドを説明しましょう。

@key_wait_p()
@@@　↓テキスト色を『白』に戻しています
@text_color(white)


@key_wait_p()
　@change_font(P1,P2)　：メッセージフォント変更
　P1：フォント名　　P2： フォントサイズ
シナリオメッセージのテキストのフォントを変更します。

※フォント名が空白時、フォント名は現在の設定のまま変更しません
※フォントサイズが「0以下」の時、フォント名とサイズを初期設定に戻します

@key_wait_p()
試しにフォントを「ＭＳ ゴシック」サイズ「25」にして見ましょう。
記述→@change_font(ＭＳ ゴシック,　25)

@key_wait_p()
@change_font(ＭＳ ゴシック,　25)
メッセージのテキストフォントが変わりましたね？
次は、元の初期値に戻します。
記述→@change_font(,　0)

@key_wait_p()
@change_font(,　0)
これで、元のフォントとサイズに戻りますよ。


@key_wait_p()
　@memo(P1)：メモ表示
　P1: メモファイル名指定
『メモ帳』等でテキストファイルを表示します。

@key_wait_p()
実際に『memoフォルダ』に有るテキストファイルを表示してみましょう。

@key_wait_p()
@memo(test.txt)
テキストファイル表示アプリが起動して、
テキストファイルが表示されていると思います。
　では次のコマンドです。

@key_wait_p()
　@click_win(X座標,Y座標,テキスト1行目,2行目・・・)　：クリック画面
　※(テキストは最大6行まで指定可能)
　　(最小は1行で、2行目以上必要の場合は2行目以降を設定して下さい)

テキストのみを表示する小ウィンドウを表示します。
小ウィンドウはクリックで消えます。
※テキストは最大6行まで指定可能です

@key_wait_p()
実際に『クリック画面』を表示してみましょう。

@key_wait_p()
@click_win(300,200,タイトル, ,クリックで閉じる)

@key_wait_p()
クリック画面が表示されましたね！
これはゲームのダメージ表示等に使用できますよ。
それでは、次にクリック画面のデザインを変えてみましょう。

@key_wait_p()
　@click_win_design(P1,P2,P3,P4,P5,P6)　：クリック画面デザイン
　P1：背景色　P2：フォント色　P3：フォント枠色
　P4：フォント名　P5：フォントサイズ　P6：フォントスタイル

クリック画面のデザインを変更できます。
※フォント名に「-1」設定時、クリック画面デザインを元に戻します
　
フォントスタイル　※初期値(1)　設定値は以下参照(※加算で複数設定可能)
　0:通常 1:太字 2:イタリック体 4:下線 8:打ち消し線 16:アンチエイリアス


@key_wait_p()
実際に『クリック画面』のデザインを変えてみます。
※背景色(BLUE)、フォント色(WHITE)、枠色(BLACK)、フォント(ＭＳ 明朝)、
サイズ(30)、スタイル(3:太字+イタリック)のクリック画面デザインに変更する

@key_wait_p()
@click_win_design(BLUE, WHITE, BLACK,ＭＳ 明朝, 30, 3)
@click_win(300,200,タイトル, ,クリックで閉じる)

@key_wait_p()
デザイン変更されたクリック画面が表示されましたね！



@key_wait_p()
次は、フラグ内容をシナリオのメッセージ上に表示させるコマンドです。

@key_wait_p()
フラグ名は「flgフォルダ」内に置いたフラグファイル(flg_xxxx.txt)
で設定します。　※「xxxxはID名：4文字の半角英数字」
フラグファイル内で記述するフラグ名は最大半角20文字です。

@key_wait_p()
　[＠f:xxxx#yyyy:]　：フラグ内容表示
　「フラグ指定」xxxx(ファイルID)yyyy(フラグ名)を設定する
　※実際のコマンドでは”@”は半角ですが、そのままではコマンドが作動してしまうので全角にしています

これらのコマンドは、他のコマンドと違ってメッセージ上に埋め込むコマンド
なので”[＠f:”と”:]”を前後に挟み、通常メッセージと区別します。

@key_wait_p()
実際にフラグ内容表示でメッセージ上に表示してみましょう。
フラグ(お金)に-100を設定して、メッセージに埋め込みます。
例：@set_flg(name#お金,-100)←「詳細はフラグ系参照」,[＠f:name#お金:]

@key_wait_p()
@set_flg(name#お金,-100)
flg(お金)の内容は → [@f:name#お金:]です。
　　　　　　　　　　　↑メッセージ上にフラグ(お金)の値が表示されましたね。

@key_wait_p()
汎用フラグ(@cnt0〜@cnt9)でも埋め込み表示が可能です。

@key_wait_p()
　[＠f:xxxx:]　：フラグ内容表示(※汎用フラグの場合)
　「フラグ指定」xxxx(汎用フラグ名：@cnt0〜@cnt9)を設定する
　※実際のコマンドでは”@”は半角ですが、そのままではコマンドが作動してしまうので全角にしています

@key_wait_p()
さらに、フラグと汎用フラグの表示に『書式の指定』が出来ます。
書式によって、埋め込む「最小桁数」等を設定する事が出来ます

@key_wait_p()
　[＠f:フラグ指定:%ZZZZ:]
　「フラグ指定」の後ろに「:%」を記述し「書式」ZZZZを指定する
　※実際のコマンドでは”@”は半角ですが、そのままではコマンドが作動してしまうので全角にしています

　「書式」　桁数　　 ：表示する最小桁数を指定します
　　　　　　0(数字)　：値が最小桁数に満たない場合、「0」で埋めます
　　　　　　+(プラス)：値が正の値の場合、先頭に「+」プラス記号を付加

@key_wait_p()
実際にフラグ内容表示で書式付きメッセージを表示してみましょう。
フラグ(お金)に100を設定して、書式に『5桁』『0埋め』『+表示』とします
例：@set_flg(name#お金,100)←[＠f:name#お金:%+05:]

@key_wait_p()
@set_flg(name#お金,100)
flg(お金)の内容は → [@f:name#お金:%+05:]です。
　　　　　　　　　　　↑メッセージ上にフラグ(お金)の値(書式付き)が
　　　　　　　　　　　　表示されましたね。

@key_wait_p()
次は、予約語をシナリオのメッセージ上に表示させるコマンドです。

@key_wait_p()
予約語名は「reserveフォルダ」内に置いた予約語ファイル(rsv_xxxx.txt)
で設定します。　※「xxxxはID名：4文字の半角英数字」
ファイルの行番号1〜1000が、予約語番号(0〜999)に対応します。　予約語ファイル内に記述する予約語名は最大半角60文字です。

@key_wait_p()
　[＠RSV:XXXX#YYY:]　：予約語表示
　　XXXX(ファイルID)　YYY(識別子)
　※実際のコマンドでは”@”は半角ですが、そのままではコマンドが作動してしまうので全角にしています

　識別子：予約語と同じ行に記述する「識別子」か「ファイル行数」を指定する
　　　　　２種類の指定方法が有ります。
　　　　　※ファイル行数は(0から数えます：予約語番号0〜999)

@key_wait_p()
これらのコマンドは、他のコマンドと違ってメッセージ上に埋め込むコマンド
なので”[＠RSV:”と”:]”を前後に挟み、通常メッセージと区別します。

@key_wait_p()
実際に予約語をメッセージ上に表示してみましょう。
ファイル(rsv_name.txt)予約語番号(0)を、埋め込みます。
例：[＠RSV:name#0:]　※「rsv_name.txt」を参照して下さい。

@key_wait_p()
@@@　『私の名前は、[@RSV:XXXXX#0:]です。』　←これはエラーになる
『私の名前は、[@RSV:name#0:]です。』
　　　　　　　↑メッセージ上に予約語(0)で定義した文字が表示されましたね。

@key_wait_p()
今度は「識別子」指定で同じ予約語を表示をしてみましょう。
ファイル(rsv_name.txt)識別子(charname1)を、埋め込みます。
例：[＠RSV:name#charname1:]　※「rsv_name.txt」を参照して下さい。

@key_wait_p()
@@@　『私の名前は、[@RSV:XXXXX#charname1:]です。』　←これはエラーになる
『私の名前は、[@RSV:name#charname1:]です。』
　　　　　　　↑識別子(charname1)で定義した文字が表示されます。
　　　　　　　　数が多くなると「識別子」の方が指定しやすくなります。

@key_wait_p()
予約語(行番号)の表示はフラグ内容表示と組み合わせる事が出来ます。
予約語(1)を埋め込む。※フラグ(0)=1
例：[＠RSV:name#[＠f:name#flg0:]:]　←＠RSV:XXXX#yyyの『yyy』の箇所を、フラグの値で埋め込む

@set_flg(name#flg0,1)
『私の名前は、[@RSV:name#[@f:name#flg0:]:]です。』
　　　　　　　↑メッセージ上に予約語(1)の値が表示されましたね。


@key_wait_p()
@text_color(WHITE)
テキスト系は以上です。
@goto_label(選択1)
@@@@@@@@@@


*麻雀系
@set_flg(ESP:0,0)
@set_flg(ESP:1,0)
@set_flg(ESP:2,0)
@set_flg(ESP:3,0)
@set_flg(ESP:4,0)
@set_flg(ESP:5,0)
@set_flg(ESP:6,0)
@set_flg(ESP:7,0)
@set_flg(ESP:8,0)
@set_flg(ESP:9,0)
@set_flg(ESP:10,0)
@set_flg(ESP:11,0)
@set_flg(ESP:12,0)
@set_flg(ESP:13,0)
@set_flg(ESP:14,0)
@set_flg(ESP:15,0)
@set_flg(ESP:16,0)
@set_flg(ESP:17,0)
@set_flg(ESP:18,0)
@set_flg(ESP:19,0)
@set_flg(ESP:20,0)
@set_flg(ESP:21,0)
@set_chapter(麻雀系)
@key_wait_p()
@char_on(0,ch特2.png,500,120)
@char_dsp()
ここで説明するコマンドは以下の通りです。
　@MJ_start()　：麻雀実行
　@MJ_first()　：麻雀初期設定
　@MJ_char()　：麻雀キャラ設定
　@MJ_setflg()　：麻雀フラグ設定
　@MJ_result_game()　：麻雀ゲーム結果取得
　@MJ_result_point()　：麻雀持ち点結果取得
　@MJ_cancel_point()　：麻雀得点取り消し

@key_wait_p()
では『@MJ_start()』麻雀実行をやってみましょう。
これをシナリオからコールするだけで、麻雀が始まります。
パラメータは不要です。

@key_wait_p()
・麻雀実行　　↓以下のようにシナリオに記述して下さい。
　
　@MJ_start()

@key_wait_p()
このコマンドをコールする事で麻雀が始まり、『1局』が終わるとシナリオに戻
ります。
麻雀を続けて行う場合は、ループ等を利用して、再度このコマンドをコールして下さい。

@key_wait_p()
では実際に麻雀を始めてみます。
1局が終われば、またシナリオに戻りますよ。

@key_wait_p()
@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@@ 　麻雀　実行
@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@MJ_start()

@key_wait_p()
どうでしょうか？
麻雀1局が動きましたか？

@key_wait_p()
今は、まだパラメータを設定していないので「1人麻雀」でしたが、これから
説明するコマンドで様々な設定の麻雀を行う事ができます。


@key_wait_p()
@text_color(ORANGE)
次は「@MJ_first()：麻雀初期設定」
を説明しましょう。


@key_wait_p()
@text_color(WHITE)
「@MJ_first()：麻雀初期設定」で面子人数や、牌画像、背景画像、牌情報、
1人分のツモ数、開始親位置、ルール情報、などを変更できます。


@key_wait_p()
麻雀初期設定のパラメータは以下の通りです。
　@MJ_first(面子人数,牌画像ID,背景画像ID,牌情報ID,1人ツモ数,
　　　　　　親キャラ位置,ルール情報ID)

@key_wait_p()
面子人数：「1〜4」を設定して下さい。
牌画像ID：「0〜99」を設定すると対応した牌画像になります。
背景画像ID：「0〜99」を設定すると対応した背景画像になります。

@key_wait_p()
牌情報ID：「0〜99」を設定すると対応した牌情報でゲームを行えます。
　　　　　「0」は通常牌のみ　「1」は赤牌3枚、ガラス牌3/4枚
　　　　　「99」は全てガラス牌となっています。　※ガラス牌とは、透けて相手に見える牌です。

@key_wait_p()
1人ツモ数：1人分のツモ数を変更する場合に設定します。
　　　　　　通常は「0」を設定して下さい。

@key_wait_p()
親キャラ位置：開始時の親の位置を決める時に設定します。
　　　　　　　(0:親はランダム　1〜4:親の面子番号)
　面子番号とは、「1」はプレイヤーの操作するキャラです。そして右隣ごとに面子番号2、面子番号3、面子番号4となります。

@key_wait_p()
ルール情報ID：「0〜99」を設定すると対応したルールでゲームを行えます。
　　　　　　「0」は食いタン有り、ダブル役満有り
　　　　　　「1」は食いタン有り、ダブル役満無し

@key_wait_p()
では実際に「@MJ_first()：麻雀初期設定」で変更して麻雀をしてみましょう。
「1人ツモ数：0」にすると、通常の麻雀と同じツモ数ですが、
今回は、「面子人数:4」「1人ツモ数：2」「親面子位置:2」でやってみます。

@key_wait_p()
@@@ 　麻雀初期設定
@@@　↓「P1 面子人数:4」「P5 1人ツモ数：2」「P6  親面子位置:2」を設定

@MJ_first(4,0,0,0,2,2,0)


@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@@ 　麻雀　実行
@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@MJ_start()


@key_wait_p()
「面子人数:4」「1人ツモ数：2」「親面子位置:2」で麻雀が動きました。
これで、面子人数や、画像等を好きにカスタマイズして麻雀を行えますね。


@key_wait_p()
@text_color(ORANGE)
面子は4人になったけど、キャラが同じじゃあつまらないですよね？
次は「@MJ_char()：麻雀キャラ設定」
を説明しましょう。

@key_wait_p()
@text_color(WHITE)
「@MJ_char()：麻雀キャラ設定」で面子ごとのキャラ設定、各面子の持ち点を
設定できます。


@key_wait_p()
麻雀キャラ設定のパラメータは以下の通りです。
　@MJ_char(面子1キャラID,面子2キャラID,面子3キャラID,面子1キャラ4D,
　　　面子1開始持ち点,面子2開始持ち点,面子3開始持ち点,面子4開始持ち点)

@key_wait_p()
面子1〜4キャラID：「0〜999」を設定すると、キャラ情報ファイルを参照します。
　　ID=0ならchrdat000.txtです(「\expand\mahjan110」フォルダ)
面子1〜4開始持ち点：麻雀開始時の各キャラの持ち点を設定します。

@key_wait_p()
キャラ情報ファイルには、以下の項目が有ります。
「名前」「キャラアイコン画像」「キャラ顔画像」「各音声ファイル名」
「CPU時の思考ルーチン(鳴き思考、得点思考)」　これらで、キャラ毎の特徴を出すことが可能です。

@key_wait_p()
では「@MJ_char()：麻雀キャラ設定」で変更して麻雀をしてみましょう。
今回は、「親：ランダム」「1人ツモ数：2」で、面子ごとに開始持ち点を変え
てみましょう。ついでに牌情報を変えて「ガラス牌」を入れてみますね。

@key_wait_p()
@@@ 　麻雀初期設定
@@@　↓「P1 面子人数:4」「P4 牌情報：1」「P5 1人ツモ数：2」「P6  親面子位置:0」を設定

@MJ_first(4,0,0,1,2,0,0)

@key_wait_p()
@@@ 　麻雀キャラ設定

@MJ_char(0,1,2,3,10001,10002,10003,10004)


@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@@ 　麻雀　実行
@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@MJ_start()


@key_wait_p()
各面子ごとにキャラが違って、持ち点も違いましたね。
これで、自作した好きなキャラで色んな条件の麻雀が楽しめます。
これをループさせれば麻雀が出来るようになりますよ。※ループはコマンド［移動系］を参照して下さい。

@key_wait_p()
@text_color(ORANGE)
更に各項目を直接数値で設定せず、フラグを使って設定する、上級コマンドを
用意しました。
「@MJ_setflg()　：麻雀フラグ設定」を説明しましょう。

@key_wait_p()
@text_color(WHITE)
「@MJ_setflg()　：麻雀フラグ設定」で各設定項目をフラグで設定できます。
　
　

@key_wait_p()
麻雀フラグ設定のパラメータは以下の通りです。
　@MJ_setflg(設定項目名,設定flg)
　　　※フラグ(flg)については、コマンド[フラグ系]を参照して下さい。


@key_wait_p()
設定項目名：以下の「項目名」一覧の内、1つを記述します。
　　途中からゲーム開始、面子人数、牌画像ID、背景画像ID、牌情報ID、
　　1人ツモ数、親キャラ位置、局数、ルール情報ID、　→続く

@key_wait_p()
　　面子1キャラID、面子2キャラID、面子3キャラID、面子4キャラID、
　　面子1持ち点、面子2持ち点、面子3持ち点、面子4持ち点、
　　供託　　←設定できる項目名は以上です。

@key_wait_p()
　※項目名「途中からゲーム開始」は麻雀実行 (@MJ_start)実行後に「1」を返
　　す内部変数です。　この項目を麻雀実行 (@MJ_start)実行後に設定する場合
　　は、必ず設定内容は「1」にして下さい。　そうでない場合は、初期値「0」を設定して下さい。

@key_wait_p()
設定flg：「設定項目名」に設定する、フラグを指定します。
　　　　※『フラグ番号(0〜999)』、又は『フラグ名』を設定
　

@key_wait_p()
例）『面子1持ち点』をフラグ『持ち点保存』から設定するには↓以下のように
　　記述します。(シナリオに記述する時は「@」前の空白は消してください)
　@MJ_setflg(面子1持ち点,持ち点保存)

@key_wait_p()
麻雀フラグ設定(@MJ_setflg)を使う事で、キャラの得点を引き継いでフラグで
設定したり、麻雀の途中経過等を、SAVEする事が可能となりますが、
やや『上級者向け』ですので、必要のない方は使用しなくても問題ありません。


@key_wait_p()
@text_color(ORANGE)
ループで麻雀は延々と続けられますが、では無限ループから抜け出すには？
そこで次は「@MJ_result_game()：麻雀ゲーム結果取得」
を説明しましょう。

@key_wait_p()
@text_color(WHITE)
麻雀ゲーム結果取得のパラメータは以下の通りです。
　@MJ_result_game(ゲーム結果flg,親キャラ位置flg,局数flg,
　　　　　　　　　あがり飜数flg,役飜数flg)　　※フラグ(flg)については、コマンド[フラグ系]を参照して下さい。

@key_wait_p()
　　※各パラメータは　『フラグ番号(0〜999)』、又は『フラグ名』を設定
　　　取得しないパラメータには『-1』を設定して下さい

@key_wait_p()
ゲーム結果flg：麻雀1局の勝ち負け結果を格納するフラグ(flg)を設定します。
　　　　　　　結果内容　-1:エラー　0:流局　1〜:勝ち面子番号


@key_wait_p()
親キャラ位置flg：次の局の親を格納するフラグ(flg)を設定します。
　　　　　　　結果内容　1〜4:次局の親の面子番号
　面子番号とは、「1」はプレイヤーの操作するキャラです。そして右隣ごとに面子番号2、面子番号3、面子番号4となります。

@key_wait_p()
局数flg：次の局数を格納するフラグ(flg)を設定します。
　　　　3桁の値が格納されます：100の位:局数　1〜10の位:本場
　　　　※南場終了したら0(東1局)に戻る

@key_wait_p()
結果内容　面子1人(0東1局　1XX南場)　面子2人(0〜1XX東場　200〜3XX南場)
　　　　　面子3人(0〜2XX東場　300〜5XX南場)
　　　　　面子4人(0〜4XX東場　400〜7XX南場)

@key_wait_p()
あがり飜数flg：あがり飜数を格納するフラグ(flg)を設定します。
　　　　結果内容　流局の場合：『0』、あがりの場合『飜数』(※ドラを含む)


@key_wait_p()
役飜数flg：役のみの飜数を格納するフラグ(flg)を設定します。
　　　　結果内容　流局の場合：『0』、あがりの場合『役のみの飜数』
　　　　　　　　　　　　　　　　　　　　　　　　　(※ドラを除く)


@key_wait_p()
では「@MJ_result_game()：麻雀ゲーム結果取得」で結果を取得しましょう。
　
　

@key_wait_p()
@@@ 　麻雀初期設定
@@@　↓「P1 面子人数:4」「P5 1人ツモ数：1」「P6  親面子位置:1」を設定

@MJ_first(4,0,0,0,1,1,0)

@key_wait_p()
@@@ 　麻雀キャラ設定

@MJ_char(0,1,2,3,10001,10002,10003,10004)


@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@@ 　麻雀　実行
@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@MJ_start()


@key_wait_p()
@@@ 　麻雀ゲーム結果取得
@@@　↓「P1 ゲーム結果flg:0」「P2 親キャラ位置flg：1」「P3 局数flg：2」「P4 あがり飜数flg:3」「P5 役飜数flg:4」を設定

@MJ_result_game(0,1,2,3,4)

@key_wait_p()
↓に結果が表示されます
ゲーム結果：[@fg:0]　親キャラ位置：[@fg:1]　局数：[@fg:2]　あがり飜数：[@fg:3]　役飜数：[@fg:4]
　ツモ数(1)なのでほとんどの方は、ゲーム結果(0:流局)、親キャラ位置(2)、局数(100:東2局)、あがり飜数(0飜)、役飜数(0飜)　になっていますね。


@key_wait_p()
@text_color(ORANGE)
もう一つの取得「@MJ_result_point()：麻雀持ち点結果取得」を説明します。
これで、持ち点が「0」になったら終了させたり、一定の持ち点を取ったら終了
させる時の「各キャラの持ち点」と「供託」を取得できます。

@key_wait_p()
@text_color(WHITE)
麻雀持ち点結果取得のパラメータは以下の通りです。
　@MJ_result_point(面子1持ち点flg,面子2flg,面子3flg,面子4flg,供託flg)
　　　※フラグ(flg)については、コマンド[フラグ系]を参照して下さい。

@key_wait_p()
　　※各パラメータは　『フラグ番号(0〜999)』、又は『フラグ名』を設定
　　　取得しないパラメータには『-1』を設定して下さい

@key_wait_p()
面子1〜4持ち点flg：1局終了後の各キャラの得点結果を格納するフラグ(flg)
　　　　　　　　　を設定します。
供託flg：1局終了後の供託を格納するフラグ(flg)を設定します。

@key_wait_p()
では先程の麻雀の結果を「@MJ_result_point()：麻雀持ち点結果取得」で
結果を取得しましょう。
　

@key_wait_p()
@@@ 　麻雀持ち点結果取得
@@@　↓「P1 面子1持ち点flg:4」「P2 面子2持ち点flg:5」「P3 面子3持ち点flg:6」「P4 面子4持ち点flg:7」「P5 供託flg:8」を設定

@MJ_result_point(4,5,6,7,8)

@key_wait_p()
↓に結果が表示されます
面子1持ち点：[@fg:4]　2持ち点：[@fg:5]　3持ち点：[@fg:6]　4持ち点：[@fg:7]
供託：[@fg:8]　　　『天和』等が出ていなければ、持ち点(10001〜10004)　供託は(0)　になっていますね。

@key_wait_p()
これらの結果を取得して、麻雀ループ終了の値を取得して下さい。
　
　

@key_wait_p()
@text_color(ORANGE)
最後に「@MJ_cancel_point()：麻雀得点取り消し」を説明します。
このコマンドをコールする事で直前に行った麻雀の得点と供託を取り消します。
　

@key_wait_p()
@text_color(WHITE)
・麻雀得点取り消し　　↓以下のようにシナリオに記述して下さい。
　　　　　　　　(シナリオに記述する時は「@」前の空白は消してください)
　@MJ_cancel_point()

@key_wait_p()
「@MJ_cancel_point()：麻雀得点取り消し」は、各キャラの持ち点と、供託が、
その局の前の値に戻ります。
　※『飜数縛り』等を行う時に使用して下さい。

@key_wait_p()
@text_color(ORANGE)
[麻雀系]全てのコマンドを説明しましたので、最後におさらいをしましょう。
　
　基本的な麻雀ゲームの作り方の参考にして下さい。

@key_wait_p()
@char_on(0,MJ1.png,50,0)
@char_dsp()
まず最初に「@MJ_first()：麻雀初期設定」「@MJ_char()：麻雀キャラ設定」で
面子人数や、画像、キャラ、持ち点などを設定します。
　

@key_wait_p()
@char_on(0,MJ2.png,0,100)
@char_dsp()
そして『ラベル』(※[移動系]コマンド参照)をシナリオに記述し、その次の行に
「@MJ_start()：麻雀実行」で1局を行い、移動系コマンドの『ラベル移動』等で
ループさせます。　この時、ループ内に「@MJ_first()：麻雀初期設定」を含めないで下さい。

@key_wait_p()
「@MJ_start()：麻雀実行」の後で「@MJ_result_game()：麻雀ゲーム結果取得」
「@MJ_result_point()：麻雀持ち点結果取得」を使う事で、1局の結果が取得で
きます。

@key_wait_p()
ループから抜ける時は、取得した結果を用いてループ外のラベルへ移動させたり、
選択コマンドでラベル移動をすればＯＫです。
　

@key_wait_p()
それでは「東場だけで終了」又は「選択肢ボタンで終了」するパターンを実行
してみますね。
是非、このシナリオファイル(000addsin1280.txt)を参照しながら、見て下さい。



@@@　↓ここから「麻雀のサンプル」
@key_wait_p()
@@@ 　麻雀初期設定
@@@　↓「P1 面子人数:4」「P4 牌情報：99」「P5 1人ツモ数：1」「P6  親面子位置:0」を設定

@MJ_first(4,0,0,99,1,0,0)

@key_wait_p()
@@@ 　麻雀キャラ設定

@MJ_char(0,1,2,3,10001,10002,10003,10004)

@key_wait_p()
まず、「@MJ_first()：麻雀初期設定」「@MJ_char()：麻雀キャラ設定」を
行います。
今回は「面子4人」「牌情報：全てガラス牌」「1人分ツモ:1」にします。

@key_wait_p()
そして『ラベル』、次に「@MJ_start()：麻雀実行」を記述します。
これで麻雀が1局実行され、ループする事で次局を続行します。
　

@key_wait_p()
その後、「@MJ_result_game()：麻雀ゲーム結果取得」「@MJ_result_point()：
麻雀持ち点結果取得」を行いますが、今回は『フラグ名』を指定しています。
フラグ名は『flg_name.txt』に登録していれば使用できます。※『\usercustom\シナリオ01シナリオ講座』フォルダ下に有ります。

@key_wait_p()
それでは麻雀が始まりますので、「東場だけで終了」又は「選択肢ボタンで終了」まで進めて下さい。



@@@　↓これが、麻雀の開始ラベルです。　ここから「麻雀ループ」
*サンプル麻雀ループ


@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@@ 　麻雀　実行
@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@MJ_start()


@@@　↓「@MJ_result_game()：麻雀ゲーム結果取得」は@MJ_start()の後に行います
@key_wait_p()
@@@ 　麻雀ゲーム結果取得
@@@　↓「P1 ゲーム結果flg:ゲーム結果取得」「P2 親キャラ位置flg：親キャラ位置取得」「P3 局数flg：局数取得」「P4 あがり飜数flg:あがり飜数取得」「P5 役飜数flg:役のみ飜数取得」を設定
@MJ_result_game(ゲーム結果取得,親キャラ位置取得,局数取得,あがり飜数取得,役のみ飜数取得)


@@@　↓「@MJ_result_point()：麻雀持ち点結果取得」は@MJ_start()の後に行います
@key_wait_p()
@@@ 　麻雀持ち点結果取得
@@@　↓「P1 面子1持ち点flg:面子1持ち点取得」「P2 面子2持ち点flg:面子2持ち点取得」「P3 面子3持ち点flg:面子3持ち点取得」「P4 面子4持ち点flg:面子4持ち点取得」「P5 供託flg:供託取得」を設定
@MJ_result_point(面子1持ち点取得,面子2持ち点取得,面子3持ち点取得,面子4持ち点取得,供託取得)


@key_wait_p()
@char_off()
@char_on(0,ch特2.png,500,120)
@char_dsp()
ゲーム結果：[@fg:ゲーム結果取得]　親キャラ位置：[@fg:親キャラ位置取得]　局数：[@fg:局数取得]　あがり飜数：[@fg:あがり飜数取得]　役飜数：[@fg:役のみ飜数取得]
　面子1持ち点：[@fg:面子1持ち点取得]　2持ち点：[@fg:面子2持ち点取得]　3持ち点：[@fg:面子3持ち点取得]　4持ち点：[@fg:面子4持ち点取得]
　供託：[@fg:供託取得]



@@@　↓東場のみで終了
@@@　局数(サンプルではflg番号:局数取得)が「400」なら、南場に入ったので『サンプル麻雀終了』へ移動する
@key_wait_p()
@flg_sel(局数取得,400,サンプル麻雀終了)

@@@　誰かが、「あがり飜数4飜で終了」する場合は・・・
@@@　↓以下のように記述して下さい
@@@　あがり飜数(サンプルではflg番号:あがり飜数取得)が「4」なら、4飜なので『サンプル麻雀終了』へ移動する
@key_wait_p()
@flg_sel(あがり飜数取得,4,サンプル麻雀終了)

@@@　誰かが、「持ち点：0で終了」する場合は・・・
@@@　↓以下のように記述して下さい
@@@　持ち点(サンプルではflg番号:面子1持ち点取得〜面子4持ち点取得)が「0以下」なら、『サンプル麻雀終了』へ移動する
@key_wait_p()
@flg_comp_sel(面子1持ち点取得,<=,0,サンプル麻雀終了)
@flg_comp_sel(面子2持ち点取得,<=,0,サンプル麻雀終了)
@flg_comp_sel(面子3持ち点取得,<=,0,サンプル麻雀終了)
@flg_comp_sel(面子4持ち点取得,<=,0,サンプル麻雀終了)


@@@　↓選択肢で終了
@key_wait_p()
麻雀を続けますか？
@menu(続ける,終了する)

@ans(1)
@@@　ラベル「*サンプル麻雀続行」へ移動します
@goto_label(サンプル麻雀続行)
@ansend()
@ans(2)
@@@　ラベル「*サンプル麻雀終了」へ移動します
@goto_label(サンプル麻雀終了)
@ansend()



*サンプル麻雀続行
@@@　↓これが、ラベル移動コマンドです。　これで「*サンプル麻雀ループ」ラベルまで移動し、ループします。
@goto_label(サンプル麻雀ループ)



@@@　↓これが、麻雀の終了ラベルです。
*サンプル麻雀終了
ここに来たという事は、無事に麻雀のループから抜けられましたね！
基本的な麻雀のゲームの作り方はこんな感じです。
様々な設定の麻雀を行えますので、色んなタイプの麻雀ゲームを作って下さい。


@key_wait_p()
@text_color(WHITE)
麻雀系は以上です。
@goto_label(選択1)
@@@@@@@@@@



*表示系
@set_chapter(表示系)
@key_wait_p()
ここで説明するコマンドは以下の通りです。
　@stage()　：背景画像表示
　@char_on()　：キャラ画像設定
　@char_dsp()　：キャラ画像表示
　@char_off()　：キャラクター情報全消去
　@zm_puru()　：背景ズーム
　@zm_char_puru()　：キャラズーム
@@　@zmset_char_move()　：キャラ画像移動設定
@@　@zm_char_piston_go()　：キャラ画像移動実行

@key_wait_p()
次は『@stage()』背景画像表示をやってみましょう。
パラメータに画像ファイルを指定して下さい。
画像ファイルはユーザーフォルダ下の背景画像フォルダに置いて下さい。
@@@画像ファイル(表示の最大は横1280、縦720)はユーザーフォルダに置いて下さい。
@@@画像ファイル(表示の最大は横800、縦600)はユーザーフォルダに置いて下さい。

@key_wait_p()
　@stage(P1)：背景画像表示
　P1:背景画像ファイル名(半角30文字まで)
　　※対応する画像形式は　BMP、JPEG、PNG　です。
　　　ちなみに「@stage(0)」とすると「背景黒」
　　　「@stage(1)」とすると「背景白」を表示します。

@stage(bk_学校昼0 1280.bmp)
@@@@stage(bk_学校昼0.bmp)
例：@stage(bk_学校昼0 1280.bmp)
と記述すると、この様に背景画像が表示されます。

@key_wait_p()
次は「@char_on()」キャラ画像設定
　　「@char_dsp()」キャラ画像表示
を説明しましょう。

@key_wait_p()
キャラ画像設定　@char_on()で背景の上に表示する画像設定をします。
このコマンドだけでは画像が表示されません。
キャラ画像表示　@char_dsp()でキャラ画像を表示します。

@key_wait_p()
キャラ画像設定のパラメータは以下の通りです。
　@char_on(ID番号,キャラ画像ファイル名,X座標,Y座標)
　キャラ画像ファイル名(半角30文字まで)※対応画像形式はBMP、PNG
※ID番号は現在未使用です。
表示できるキャラクターの最大数は『10』です。
@@表示できるキャラクターの最大数は『5』です。
それより多く設定しても反映しません。

@key_wait_p()
キャラ画像表示　@char_dsp()
　こちらはパラメータは無しです。

@key_wait_p()
@char_on(0,ch特2.png,400,120)
@char_dsp()
例：@char_on(0,ch特2.png,400,120)
　　@char_dsp()
キャラが表示されましたか？
キャラ画像ファイルは透明色として緑色(RGB:0,255,0)を指定しています。
表示しない場所は透明色で塗りつぶしてください。

@key_wait_p()
@char_on(0,ch特2.png,0,120)
@char_dsp()
　@char_on()を複数設定すれば、キャラを2個以上同時に表示できます。
　
次はキャラを消して見ましょう。

@key_wait_p()
@char_off()
@char_dsp()
　キャラが消えましたか？　コマンドは以下の通りです。
キャラクター情報全消去　@char_off(パラメータ無し)
これもキャラ情報を消すだけなので@char_dsp()で表示して下さい。

@key_wait_p()
　@zm_puru(ズーム倍率,ゆれ方向)　背景ズーム
一旦ズーム倍率まで拡大し、その後20％倍率でズームしたまま、揺らします
　
　ズーム倍率:0〜900　ズーム無しは0を設定(+20%(1.2倍)なら「20」設定)
　ゆれ方向(0:横方向 1:縦方向)
　揺れは画面をクリックするまで続きます。
@key_wait_p()
@zm_puru(50,1)
例：@zm_puru(50,1)
背景が50%ズームし、縦方向に揺れますね。

@key_wait_p()
@char_on(0,ch特2.png,200,120)
@char_dsp()
　@zm_char_puru(ズーム倍率,ゆれ方向)　キャラズーム
キャラ画像のみ一旦ズーム倍率まで拡大し、その後20％倍率でズームしたまま、
揺らします
　ズーム倍率:0〜900　ズーム無しは0を設定(+20%(1.2倍)なら「20」設定)
　ゆれ方向(0:横方向 1:縦方向)
　揺れは画面をクリックするまで続きます。
@key_wait_p()
@zm_char_puru(50,0)
例：@zm_char_puru(50,0)
キャラが50%ズームし、横方向に揺れますね。


@key_wait_p()
@char_off()
@stage(0)
表示系は以上です。
@goto_label(選択1)
@@@@@@@@@@


*名前系
@key_wait_p()
@set_chapter(名前系)
ここで説明するコマンドは以下の通りです。
　@name()　：名前表示
　@name_cls()　：名前消去
　@name_color()　：色つき名前表示

@key_wait_p()
　@name(P1)：名前ウィンドウ表示
　P1：名前(半角30文字まで)
@key_wait_p()
　@name_cls()：名前ウィンドウ消去
　パラメータ無し

@key_wait_p()
@char_on(0,ch特2.png,400,120)
@char_dsp()
名前を表示して見ましょう。
例：@name(説明子)

@key_wait_p()
@name(説明子)
これで名前が表示されます。
パラメータに表示する名前を設定して下さい。
次は名前を消しましょう。

@key_wait_p()
@name_cls()
名前が消えましたね。
コマンド「@name_cls()」を記述するだけでＯＫです。
パラメータは無しです。

@key_wait_p()
色つきの名前にしたい場合は
　コマンド「@name_color()」
を使ってください。

@key_wait_p()
　@name_color(P1,P2)
　P1：名前(半角30文字まで)
　P2:色指定(WHITE,RED等)　※色指定はコマンドマニュアルの【初めに】を参照
名前の色を変えてみましょう
例：@name_color(説明子,PINK)

@key_wait_p()
@name_color(説明子,PINK)
名前がピンクになりました。

@key_wait_p()
ちなみに、名前には予約語挿入が使用できます。
例：@name([＠RSV:name#0:])
※”@”は半角にして下さい。

@key_wait_p()
@name([@RSV:name#0:])
予約語が名前に表示されましたね。

@key_wait_p()
@name_cls()
@char_off()
@char_dsp()
名前系は以上です。
@goto_label(選択1)
@@@@@@@@@@


*選択系
@set_chapter(選択系)
@key_wait_p()
@char_on(0,ch特2.png,200,120)
@char_dsp()
ここで説明するコマンドは以下の通りです。
　@menu()　：メニュー選択
　@ans()　：選択分岐ラベル

　@ansend()　：選択分岐終端
　@menu_pos()　：メニュー選択(位置指定)
　@list_menu()：リストメニュー型選択(メッセージWINに表示)

　@menu_free()　：メニュー選択(位置フリー)
　@menu_dis()　：選択肢無効
　@menu_dis_abl()　：選択肢有効/無効

　@menu_visible()　：選択肢表示/非表示
　@menu_font()　：選択肢フォント変更
　@menu_kidoku_mark()　：選択済マーク表示/非表示

　@menu_back_color()　：選択メニュー背景色

@key_wait_p()
最初は『メニュー選択：@menu()』です。
選択肢を表示し、選択決定後に指定ラベルに移動します。
　
　@menu(P1,P2,・・・)　：メニュー選択
　P1,P2〜:選択肢表示タイトル
　※選択肢は6個まで可能

@key_wait_p()
そして、以下の２つのコマンドを使用してください。
　@ans(P1)　：選択分岐ラベル
　@ansend()　：選択分岐終端
@key_wait_p()
　@ans(P1)　：選択分岐ラベル
　P1:選択肢番号(1〜)
　これは選択したメニュー選択後の移動ラベルになります。

@key_wait_p()
　@ansend()　：選択分岐終端
そして、選択分岐ラベルの終端に、このコマンドを使用してください。

@key_wait_p()
『メニュー選択(位置指定)：@menu_pos』は選択肢の場所を指定出来ます。
@key_wait_p()
　@menu_pos(P1,P2,P3,P4,P5,・・・)　：メニュー選択(位置指定)
　P1:開始X座標　P2:開始Y座標　P3:メニュー幅　P4:選択肢１表示タイトル
　P5:選択肢２表示タイトル　※選択肢は10個まで可能

@key_wait_p()
では、選択肢を表示して見ましょう。
「選択肢1,選択肢2」どちらかを選択して下さい。
例：@menu_pos(200,100,400,選択肢1,選択肢2)

@key_wait_p()
@menu_pos(200,100,400,選択肢1,選択肢2)


ここは飛ばされる
ここは飛ばされる
ここは飛ばされる
ここは飛ばされる


@@@@@　選択肢１の移動ラベル
@ans(1)
あなたは選択肢１を選びましたね！
このように『@ans(1)』の場所に移動します。
そして『@ansend()』まで実行します。
選択肢2のラベル『@ans(2)』から『@ansend()』は飛ばされます。
@ansend()

@@@@@　選択肢２の移動ラベル
@ans(2)
あなたは選択肢２を選びましたね！
このように『@ans(2)』の場所に移動します。
そして『@ansend()』まで実行します。
選択肢1のラベル『@ans(1)』から『@ansend()』は飛ばされます。
@ansend()

@key_wait_p()
『リストメニュー型選択：@list_menu』はメッセージウィンドウに選択肢を表示します。
@key_wait_p()
　@list_menu(P1,P2,・・・)
　P1:選択肢１
　P2:選択肢２　※選択肢は20個まで可能

@key_wait_p()
では、リストメニュー型選択を表示して見ましょう。
例：@list_menu(リスト1,リスト2,リスト3)

@key_wait_p()
@list_menu(リスト1,リスト2,リスト3)
@ans(1)
あなたはリスト１を選びましたね！
@ansend()
@ans(2)
あなたはリスト２を選びましたね！
@ansend()
@ans(3)
あなたはリスト３を選びましたね！
@ansend()

@key_wait_p()
『メニュー選択(位置フリー)：@menu_free』は選択肢を自由な位置に表示します。
@key_wait_p()
メニュー選択(位置フリー)
　@menu_free(P1)：選択肢ボタンの位置をボタン別に自由に指定できます。
　　P1:メニュー位置ファイル名(半角30文字まで)
　　　メニュー位置ファイルは選択ボタンの位置とキャプションを設定する
　　　ファイルです。
　　　※選択肢は100個まで可能
メニュー位置ファイルは、選択肢毎に以下の様に記述して下さい。
「選択肢タイトル,X座標,Y座標,幅,高さ」
例：顔,370,140,60,50

@key_wait_p()
では、メニュー選択(位置フリー)を表示して見ましょう。
例：@menu_free(menu_0.txt)

@menu_free(menu_0.txt)
@ans(1)
あなたは「顔」を選びましたね！
@ansend()
@ans(2)
あなたは「右乳」を選びましたね……
@ansend()
@ans(3)
あなたは「左乳」を選びましたね……
@ansend()
@ans(4)
あなたは「腹」を選びましたね！
@ansend()

@key_wait_p()
選択肢無効
　@menu_dis(選択肢番号)
　　　選択肢番号(1〜)：無効にする選択肢番号を設定する
　　　※選択肢1を無効にする場合は「1」を設定
　　　※メニューコマンドの直前に使用する事

@key_wait_p()
では、選択肢「右乳」を無効にしてみましょう。
例：@menu_dis(2)
　　@menu_free(menu_0.txt)

@key_wait_p()
@menu_dis(2)
@menu_free(menu_0.txt)
@ans(1)
あなたは「顔」を選びましたね！
@ansend()
@ans(2)
あなたは「右乳」を選びましたね……
@ansend()
@ans(3)
あなたは「左乳」を選びましたね……
@ansend()
@ans(4)
あなたは「腹」を選びましたね！
@ansend()

@key_wait_p()
　@menu_dis_abl(選択肢番号,有効無効)：選択肢有効/無効
　　　選択肢番号(0 又は1〜100)：無効にする選択肢番号を設定する
　　　有効無効：0:無効　0以外:有効

　※このコマンドはメニューコマンドの直前に使用する事
　※選択肢番号は、選択肢1を無効にする場合は「1」を設定
　※選択肢番号が「0」の時は、全選択肢を変更します。

@key_wait_p()
では、一旦全選択肢を「無効」にし、選択肢「顔」を有効にしてみましょう。
例：@menu_dis_abl(0,0)
　　@menu_dis_abl(1,1)

@key_wait_p()
@menu_dis_abl(0,0)
@menu_dis_abl(1,1)
@menu_free(menu_0.txt)
@ans(1)
あなたは「顔」を選びましたね！
@ansend()
@ans(2)
あなたは「右乳」を選びましたね……
@ansend()
@ans(3)
あなたは「左乳」を選びましたね……
@ansend()
@ans(4)
あなたは「腹」を選びましたね！
@ansend()

@key_wait_p()
　@menu_visible(選択肢番号,表示/非表示)：選択肢表示/非表示
　　　選択肢番号(0 又は1〜100)：表示/非表示にする選択肢番号を設定する
　　　表示/非表示　0:非表示　0以外:表示

　表示/非表示にする選択肢番号を設定します。
　表示にした場合、その選択肢は自動的に『有効』となります。
　非表示にした場合、その選択肢は自動的に『無効』となります。

　※このコマンドはメニューコマンドの直前に使用する事
　※選択肢番号は、選択肢1を変更する場合は「1」を設定
　※選択肢番号が「0」の時は、全選択肢を変更します。

　※非表示になった選択肢は、メニューに表示されません
　　(同時に無効になります)

@key_wait_p()
では、一旦全選択肢を「非表示」にし、選択肢「顔」を表示にしてみましょう。
例：@menu_visible(0,0)
　　@menu_visible(1,1)

@key_wait_p()
@menu_visible(0,0)
@menu_visible(1,1)
@menu_free(menu_0.txt)
@ans(1)
あなたは「顔」を選びましたね！
@ansend()
@ans(2)
あなたは「右乳」を選びましたね……
@ansend()
@ans(3)
あなたは「左乳」を選びましたね……
@ansend()
@ans(4)
あなたは「腹」を選びましたね！
@ansend()

@char_off()
@char_dsp()
@key_wait_p()
　@menu_font(フォント名, フォントサイズ)　：選択肢フォント変更
　P1：フォント名　　P2： フォントサイズ
選択肢のフォントを変更します。

※フォント名が空白時、フォント名は現在の設定のまま変更しません
※フォントサイズが「0以下」の時、フォント名とサイズを初期設定に戻します


@key_wait_p()
試しにフォントを「ＭＳ 明朝」サイズ「25」にして見ましょう。
記述→@menu_font(ＭＳ 明朝,　25)

@key_wait_p()
@menu_font(ＭＳ 明朝,　25)
@menu(フォント変更,フォント変更)
選択肢のフォントが変わりましたね？

@key_wait_p()
@@　元に戻す
@menu_font(,　0)


@key_wait_p()
　@menu_kidoku_mark(表示/非表示)　：選択済マーク表示/非表示
　　P1：表示/非表示　0:非表示　0以外:表示
既に選択した選択メニューの選択済マークの表示/非表示を変更します。

@key_wait_p()
@char_on(0,rm_select00a.JPG,200,120)
@char_dsp()
この選択肢(2)の左上の赤い印が選択済マークです。
※表示の場合、メニューの左上に「赤いマーク」が表示されます
※初期値は「表示」です


@key_wait_p()
@char_off()
@char_dsp()
　@menu_back_color(背景色指定,透過率)　：選択メニュー背景色
　P1:色指定(WHITE,RED等)　※色指定はコマンドマニュアルの【初めに】を参照
　P2:透過率(0〜256、256：塗りつぶし、初期値：50)

　選択メニューの背景色と透過率を変えます
※背景色指定が『空白』の場合は初期値に戻ります
※初期値は「色：LIME」の「透過率：50」です

@key_wait_p()
選択肢の背景色と透過率を変えてみましょう
例：@menu_back_color(SILVER,256)

@key_wait_p()
@menu_back_color(SILVER,256)
@menu(選択肢背景変更,選択肢背景変更)

選択肢の背景色が変わっていますね。
透過率も「256」設定なので『塗りつぶし』になっています。

@key_wait_p()
@@　元に戻す
@menu_back_color()


@key_wait_p()
選択肢コマンドの使用方法は以上です。
@goto_label(選択1)
@@@@@@@@@@


*移動系
@key_wait_p()
@set_chapter(移動系)
ここで説明するコマンドは以下の通りです。
　@goto_label()　：ラベル移動
　@goto_file()　：別シナリオ移動
　@goto_file_label()　：別シナリオのラベル移動
　@return_file()　：移動元ファイルに戻る

@key_wait_p()
『ラベル移動』です。これでシナリオの好きな箇所に移動できます。
　@goto_label(P1)：ラベル移動
　　P1：移動先ラベル(*は不要)

実際にラベル移動してみましょう。
ラベルとは、シナリオの行の先頭に『*』を付けた文字列です。
例：@goto_label(ラベルテスト)

@key_wait_p()
@goto_label(ラベルテスト)

ここはラベル移動で表示されない
ここはラベル移動で表示されない
ここはラベル移動で表示されない
ここはラベル移動で表示されない
ここはラベル移動で表示されない

*ラベルテスト
@key_wait_p()
ちゃんとラベル移動されましたね。
　@goto_label()コマンドからラベル(*ラベルテスト行)まで実行箇所が飛んでいます。

@key_wait_p()
次は『別シナリオ移動』と『別シナリオのラベル移動』です。
これで別シナリオファイルに移動できます。
『別シナリオのラベル移動』はラベル指定が出来ます。

@key_wait_p()
　@goto_filel(P1)：別シナリオ移動
　　P1：移動先シナリオファイル名(半角30文字まで)
　　※指定ファイルの先頭行に移動します。

@key_wait_p()
　@goto_file_label(P1,P2)：別シナリオのラベル移動
　　P1：移動先シナリオファイル名(半角30文字まで)
　　P2：移動先ラベル(*は不要)

@key_wait_p()
　ついでに戻るコマンドも紹介しましょう。
　@return_file()　：移動元ファイルに戻る

@key_wait_p()
　別シナリオ移動コマンド @goto_file()や
　別シナリオのラベル移動コマンド @goto_file_label()で移動した後、
　元ファイルに戻りたい時、@return_file()で、移動元ファイルの続きの行からシナリオを再開します。

@key_wait_p()
@char_on(0,comd_return.jpg,0,0)
@char_dsp()
別ファイル移動(ラベル移動)と移動元リターンコマンドの関係は、
この図の通りです。
イメージして頂けたでしょうか？

@key_wait_p()
では別ファイルに移動しましょう。
移動先のシナリオファイル(001addsin1280.txt)をメモ帳などで開いて下さい。
例：@goto_file_label(001addsin1280.txt,ラベル2)

@goto_file_label(001addsin1280.txt,ラベル2)

@@↑※@return_file()コマンドで、この行に戻ります。

@key_wait_p()
戻って来ましたね。　@return_file()コマンドは
このように、@goto_file()や@goto_file_label()コマンドの直後に帰ってきます。

@key_wait_p()
移動系は以上です。
@goto_label(選択1)
@@@@@@@@@@


*次ページ
@goto_file_label(001addsin1280.txt,選択2)
