*ラベル1
シナリオ作成その２

*ラベル2
別ファイルに移動しました！
シナリオファイルを分割する時などに使用してください。

@key_wait_p()
次は元の位置に戻ってみましょう。
　@return_file()コマンドを使用します。

@return_file()


*選択2
@name_cls()
@char_on(0,ch特2.png,900,120)
@char_dsp()
　
講座メニュー選択2

@menu_pos(200,50,800,音系,フラグ系,演出系,サブウィンドウ系,システム系,終了系,前ページ)
@@ @menu(音系,フラグ系,演出系,サブウィンドウ系,システム系,終了系,前ページ)
@@@@@　音系
@ans(1)
@goto_label(音系)
@ansend()

@@@@@　フラグ系
@ans(2)
@goto_label(フラグ系)
@ansend()

@@@@@　演出系
@ans(3)
@goto_label(演出系)
@ansend()

@@@@@　サブウィンドウ系
@ans(4)
@goto_label(サブウィンドウ系)
@ansend()

@@@@@　システム系
@ans(5)
@goto_label(システム系)
@ansend()

@@@@@　終了系
@ans(6)
@goto_label(終了系)
@ansend()

@@@@@　前ページ
@ans(7)
@char_off()
@char_dsp()
@goto_file_label(000addsin1280.txt,選択1)
@ansend()


*音系
@key_wait_p()
@set_chapter(音系)
@name(説明子)
ここで説明するコマンドは以下の通りです。
　@efc_start()　：効果音開始
　@snd_start()　：サウンド開始
　@snd_stop()　：サウンド停止

@key_wait_p()
　@efc_start(P1,P2)　：効果音開始。　主に短い音声の再生に使用します。
　P1：ファイル名(半角30文字まで)　※使用できるのはWAV形式のみ
　P2：再生モード(0:通常再生 1:ループ再生 2:再生終了まで待つ)

効果音を鳴らしてみましょう。
例：@efc_start(ksonic0.wav,0)

@key_wait_p()
@efc_start(ksonic0.wav,0)
これで効果音が鳴ります。
　
続いてサウンドBGMです。　サウンド停止も同時に説明します。

　@snd_start(P1,P2)　：サウンド開始　主に長めの音声の再生に使用します。
　P1：ファイル名(半角30文字まで)　※使用できるのはMP3形式のみ
　P2：再生モード(0:通常再生 1:ループ再生 2:再生終了まで待つ)

　@snd_stop()：サウンド停止
　　パラメータは有りません。

@key_wait_p()
BGMを鳴らしてみましょう。
例：@snd_start(sht_a02ステージ1.mp3,0)

@key_wait_p()
@snd_start(sht_a02ステージ1.mp3,0)
BGMが鳴っていますね？
　@snd_stop()で再生中のBGMや効果音が停止します。

@key_wait_p()
@snd_stop()
BGMが停止しました。

@key_wait_p()
音系は以上です。
@goto_label(選択2)
@@@@@@@@@@

*フラグ系
@key_wait_p()
@set_chapter(フラグ系)
@name(説明子)
ここで説明するコマンドは以下の通りです。
　@set_flg()　：フラグ設定
　@add_flg()　：フラグ加算
　@copy_flg()　：フラグコピー(代入)
　@random_flg()　：フラグ乱数設定
　@calc_flg()　：フラグ間計算
　@setcomp_flg()　：条件付フラグ設定
　@addcomp_flg()　：条件付フラグ加算
　@flg_comp_sel()　：フラグ比較分岐
　@flg_plu_mi()　：フラグ符号反転

@key_wait_p()
では『フラグ』を説明しましょう。
フラグを使用して分岐に条件を持たせることが出来ます。
フラグを使用するには「フラグ名称」を設定する必要があります。

フラグ名称は「flg_XXXX.txt」で設定します。1つの名称は最大半角20文字です。
※(XXXXはフラグファイルID:英数字4文字)
詳細は「コマンド説明」の『初めに』を参照して下さい。　また、実際の例は「flg_name.txt」等を参照して下さい。

@key_wait_p()
まず、フラグに値を設定するコマンドを、２つ説明しましょう。
フラグ設定と、フラグ加算です。

@key_wait_p()
　@set_flg(P1,P2)　：フラグ設定
　P1：フラグ名称　P2：設定値(フラグ、又は数字)
　フラグ名称に「ESP:XXX」とすると、共有メモリに設定出来ます。共有メモリは拡張シナリオで使用します。
@key_wait_p()
使用例）ファイル(flg_name.txt)のフラグ名称=「お金」に、100を設定
　@set_flg(name#お金,100)

@key_wait_p()
　@add_flg(P1,P2)　：フラグ加算
　P1：フラグ名称　P2：加算値(フラグ、又は数字)
　フラグ番号に「ESP:XXX」とすると、共有メモリに設定出来ます。共有メモリは拡張シナリオで使用します。
@key_wait_p()
使用例）ファイル(flg_name.txt)のフラグ名称=「お金」に、100を加算
　@add_flg(name#お金,100)


@key_wait_p()
ここでフラグの『配列要素』の指定を説明しましょう。
　1次元配列のフラグ『借金』は配列要素『2』あります(参照:flg_name,txt)
　これは借金[0]と、借金[1]の2個の変数が有る事を意味します。　※指定要素番号が1〜2では無い事に注意！

では、配列指定でフラグに値を設定してみましょう。
使用例）ファイル(flg_name.txt)のフラグ名称=「借金[0]」に、100を設定
　@set_flg(name#借金[0],100)

@key_wait_p()
フラグの『配列要素』は最大4次元まで指定可能です。
　4次元配列のフラグ『配列TEST』は配列要素『2,3,4,10』です。
　これは配列TEST[0][0][0][0]〜配列TEST[1][2][3][9]までの変数が有る事を意味します。

　この時、配列要素の総数は「2×3×4×10」で「240個」になります。

@key_wait_p()
4次元でも、配列指定でフラグに値を設定してみましょう。
使用例）フラグ名称=「配列TEST[1][2][3][9]」に、-500を設定
　@set_flg(name#配列TEST[1][2][3][9],-500)

@key_wait_p()
配列フラグの指定方法は、全てのコマンドで共通の書式です。
また、配列指定番号には『フラグの埋め込み』が使用できます。
　フラグの埋め込み書式→[＠f:xxxx#yyyy:]　※テキスト系参照

さらに、配列指定番号には『汎用フラグ』が使用できます。
例）汎用フラグ『@cnt0』を配列指定番号に使用する場合
　@set_flg(name#借金[@cnt0],100)



@key_wait_p()
では次に、フラグの値を他のフラグに代入するコマンドです。
　@copy_flg(コピー元フラグ,コピー先フラグ)　：フラグコピー(代入)
　コピー先フラグに「ESP:XXX」とすると、共有メモリに設定出来ます。共有メモリは拡張シナリオで使用します。
@key_wait_p()
使用例）ファイル(flg_name.txt)のコピー元フラグ名称「お金」から、
　　　　コピー先フラグ名称「借金」にコピー
　@copy_flg(name#お金,name#借金)

@key_wait_p()
次は、フラグ間計算です。@calc_flg()
　
　
　@calc_flg(値1,計算符号,値2,結果フラグ)
　　「値1(フラグ、又は数字)」と「値2(フラグ、又は数字)」を計算符号で指定
　　した計算を行い、結果を「結果フラグ」に代入
※計算符号：'+'(加算),'-'(減算),'*'(かけ算),'/'(割り算),'\'(割り算余り)
@key_wait_p()
使用例）ファイル(flg_name.txt)のフラグ「お金」から、「借金」を引き、
　　　　計算結果をフラグ「結果」に指定
　@calc_flg(name#お金,-,name#借金,name#結果)

@key_wait_p()
値1と値2は『数字』を指定してもOKです。
使用例）ファイル(flg_name.txt)のフラグ「お金」を10倍し「結果」に指定
　@calc_flg(name#お金,*,10,name#結果)

@key_wait_p()
次は、フラグにランダム値を設定するコマンドです。
　@random_flg(P1,P2,P3)　：フラグ乱数設定(乱数範囲:2〜32768で設定する)
　P1：結果フラグ名称　P2：乱数開始値　P3：乱数範囲
@key_wait_p()
使用例）ファイル(flg_name.txt)のフラグ名称「お金」に、
　　　　1〜10の範囲の乱数を発生させる
　@random_flg(name#お金,1,10)

使用例）ファイル(flg_name.txt)のフラグ名称「借金」に、
　　　　-3〜3の範囲の乱数を発生させる(※範囲は7)
　@random_flg(name#借金,-3,7)

@key_wait_p()
次は『条件付き』で処理を行うコマンドです。



@key_wait_p()
  @setcomp_flg(P1,P2,P3,P4,P5)  ：条件付フラグ設定
  P1:条件値(フラグ又は値) P2:条件式 P3:比較値(フラグ又は値)
  P4:結果フラグ P5:設定値(フラグ又は値)

　条件が成立した時のみフラグに値を設定します。
　※P2条件式：<,>,=,!=,<=,>=のいずれかを設定

@key_wait_p()
使用例）ファイル(flg_name.txt)のフラグ「お金」が「0未満」の時、
　　　　フラグ「借金」に100を設定
　@setcomp_flg(name#お金,<,0,name#借金,100)

@key_wait_p()
  @addcomp_flg(P1,P2,P3,P4,P5)  ：条件付フラグ加算
  P1:条件値(フラグ又は値) P2:条件式 P3:比較値(フラグ又は値)
  P4:結果フラグ P5:加算値(フラグ又は値)

　条件が成立した時のみフラグに値を加算します。
　※P2条件式：<,>,=,!=,<=,>=のいずれかを設定

@key_wait_p()
使用例）ファイル(flg_name.txt)のフラグ「お金」が「0以上」の時、
　　　　フラグ「借金」に-100を加算
  @addcomp_flg(name#お金,>=,0,name#借金,-100)


@key_wait_p()
次は、フラグの値と比較値を比較し、『条件式に一致』した場合に指定ラベルに
移行します。

@key_wait_p()
　@flg_comp_sel(P1,P2,P3,P4)　：フラグ比較分岐
　P1:条件値(フラグ又は値)　P2:条件式　P3:比較値(フラグ又は値)
　P4:移行ラベル

　※P2条件式：<,>,=,!=,<=,>=のいずれかを設定

@key_wait_p()
使用例）ファイル(flg_name.txt)のフラグ「お金」が「99以上」でラベル移動
例：@set_flg(name#お金,100)
　　@flg_comp_sel(name#お金,>=,99,フラグ比較分岐ラベル)

@set_flg(name#お金,100)
@flg_comp_sel(name#お金,>=,99,フラグ比較分岐ラベル)

@key_wait_p()
ここは飛ばされる

*フラグ比較分岐ラベル
フラグ(name#お金)が99より大きいのでラベル移動しましたね！
　
次は、2つのフラグの値を比較し、『条件式に一致』した場合の使用例です。


@key_wait_p()
使用例）ファイル(flg_name.txt)のフラグ「お金」が「借金」以上でラベル移動
例：@set_flg(name#お金,100)　と　@set_flg(name#借金,99)
　　@flg_comp_sel(name#お金,>=,name#借金,フラグ間比較分岐ラベル)

@set_flg(name#お金,100)
@set_flg(name#借金,99)
@flg_comp_sel(name#お金,>=,name#お金,フラグ間比較分岐ラベル)

@key_wait_p()
ここは飛ばされる

*フラグ間比較分岐ラベル
フラグ(name#お金)がフラグ(name#借金)以上なのでラベル移動しましたね！
　


@key_wait_p()
次はフラグに設定された『値の符号を反転する』コマンドです。
自作ゲーム等では、以外に符号の反転が必要とする事が出てきます。


@key_wait_p()
  @flg_plu_mi(P1)  ：フラグ符号反転
  P1:フラグ


@key_wait_p()
使用例）ファイル(flg_name.txt)のフラグ「借金」の符号を反転する
　@flg_plu_mi(name#借金)


@key_wait_p()
フラグの説明は以上です。
@goto_label(選択2)
@@@@@@@@@@

*演出系
@key_wait_p()
@set_chapter(演出系)
@stage(bk_学校昼0 1280.bmp)
@@@stage(bk_学校昼0.bmp)
@name(説明子)
ここで説明するコマンドは以下の通りです。
　@dark()　：暗転表示
　@light()　：明転表示
　@flash()　：フラッシュ表示
　@flash3()　：連続フラッシュ表示
　@dark_moment(P1)　：暗転フラッシュ表示
　@quake()　：画像振動
　@quake_advc()　：画像振動(上級設定)

@key_wait_p()
　@dark(P1)　：暗転表示
　P1：遅延時間(単位10ms)
　画面を暗転(黒)します。遅延時間を設定した時間だけ、次のコマンド移行を遅らせます。

@key_wait_p()
遅延時間1秒で暗転させます。
例：@dark(100)

@key_wait_p()
@dark(100)
こんな感じです。
ちなみにキャラ情報も消去されるので注意して下さい。

@key_wait_p()
@stage(bk_学校昼0 1280.bmp)
@@@stage(bk_学校昼0.bmp)
@char_on(0,ch特2.png,400,120)
@char_dsp()
　@light(P1)　：明転表示
　P1：遅延時間(単位10ms)
　画面を明転(白)します。遅延時間い設定した時間だけ、次のコマンド移行を遅らせます。

@key_wait_p()
遅延時間2秒で明転させます。
例：@light(200)

@key_wait_p()
@light(200)
画面が白くなりました。
これもキャラ情報が消去されます。

@key_wait_p()
@stage(bk_学校昼0 1280.bmp)
@@@stage(bk_学校昼0.bmp)
@char_on(0,ch特2.png,400,120)
@char_dsp()
　@flash(P1)　：フラッシュ表示
　P1：表示時間(単位10ms)
　画面を一瞬白くします。

@key_wait_p()
0.2秒でフラッシュさせます。
例：@flash(20)

@key_wait_p()
@flash(20)
一瞬だけ白くなりましたね。

@key_wait_p()
　@flash3()　：連続フラッシュ表示
　パラメータ無し
　画面を一瞬明るくする演出を連続で行います。

@key_wait_p()
@flash3()
色んな場面で使えますね。

@key_wait_p()
　@dark_moment(P1)　：暗転フラッシュ表示
　P1：表示時間(単位10ms)
　『@flash()』の逆で、一瞬ウィンドウが暗転し、徐々に元に戻っていきます。

@key_wait_p()
0.8秒で暗転フラッシュさせます。
例：@dark_moment(80)

@key_wait_p()
@dark_moment(80)
一瞬だけ黒くなりましたね。

@key_wait_p()
　@quake(P1,P2)　：画像振動
　P1：振動方向　0:横振動 1:縦振動
　P2：振動回数

@key_wait_p()
縦振動を5回します。
例：@quake(1,5)

@key_wait_p()
@quake(1,5)
画像が縦に5回振動しましたね。

@key_wait_p()
　@quake_advc(P1,P2,P3,P4)　：画像振動(上級設定)
　　P1:振動回数(1〜99)　　　 ／　　P2:間隔時間(1〜100)(単位10ms)
　　P3:揺れ幅(画面の幅まで)　／　　P4:揺れ高さ(画面の高さまで)

@key_wait_p()
『@quake_advc()：画像振動(上級設定)』は『@quake()』の上級設定で、
ななめ揺れや、振動時間の間隔、振動幅等、より細かい振動設定が行えます。

@key_wait_p()
振動回数(10)、間隔時間(単位10ms)(15)、揺れ幅(20)、揺れ高さ(-10)
例：@quake_advc(10,15,20,-10)

@key_wait_p()
@quake_advc(10,15,20,10)
画像がななめに、ゆっくり揺れましたね。

@key_wait_p()
演出系は以上です。
@dark(100)
@goto_label(選択2)
@@@@@@@@@@

*サブウィンドウ系
@key_wait_p()
@set_chapter(サブウィンドウ系)
@name(説明子)
ここで説明するコマンドは以下の通りです。
　@winsub_set()　：サブウィンドウ画像設定
　@winsub_on()　：サブウィンドウ表示
　@winsub_off()　：サブウィンドウ非表示
　@wsub_txt_set()　：サブウィンドウ情報設定
　@wsub_clear()　：サブウィンドウ情報全削除

@key_wait_p()
　@winsub_set(P1)　：サブウィンドウ画像設定
　　P1：サブウィンドウ画像ファイル名(半角30文字まで)
　このコマンドはサブウィンドウ画像ファイル名を設定するだけで表示は行いません。

サブウィンドウファイルはキャラ画像ファイルと同様に、
透明色として緑色(RGB:0,255,0)を指定しています。
表示しない場所は透明色で塗りつぶしてください。

@key_wait_p()
　@winsub_on()　：サブウィンドウ表示
　　パラメータ無し
　このコマンドで設定されたサブウィンドウを表示します。

サブウィンドウ「winsub0.bmp」を表示します。
例：@winsub_set(winsub0.bmp),@winsub_on()

@key_wait_p()
@winsub_set(winsub0.bmp)
@winsub_on()
　サブウィンドウが表示されましたね。

@key_wait_p()
　@winsub_off()　：サブウィンドウ非表示
　　パラメータ無し
　このコマンドで設定されたサブウィンドウを消します。

@key_wait_p()
@winsub_off()
　サブウィンドウが消えましたね。

@key_wait_p()
　@wsub_txt_set(P1)　：サブウィンドウ情報設定
　　P1：サブウィンドウ情報ファイル名(半角30文字まで)
　サブウィンドウに表示するテキスト等を設定するファイルです。

設定内容は「winsub0.txt」「winsub1.txt」を参照して下さい。
このコマンドを複数回(最大10回まで)呼ぶ事で、追加で
『他のサブウィンドウ情報ファイル』を設定する事が出来ます。

@key_wait_p()
@@ @set_flg(name#flg0,100)
@set_flg(name#主人公HP,50)
@set_flg(name#主人公HP最大,100)
@wsub_txt_set(winsub0.txt)
@wsub_txt_set(winsub1.txt)
@winsub_on()
　サブウィンドウに設定情報が表示されましたね。


@key_wait_p()
　@wsub_clear()　：サブウィンドウ情報全削除
　　パラメータ無し
　設定されたサブウィンドウ画像と情報を全て未設定状態にします。

新たな設定の『サブウィンドウ』を表示する時に、前の情報を消す為に使用して
下さい。


@key_wait_p()
@wsub_clear()
@winsub_off()
サブウィンドウ系は以上です。
@goto_label(選択2)
@@@@@@@@@@

*システム系
@set_chapter(システム系)
@name(説明子)
ここで説明するコマンドは以下の通りです。
　@set_chapter()　：チャプター設定
　@button_dis()　：システムボタン無効設定
　@msg_full()　：メッセージ表示固定
　@change_msg_win_h()　：メッセージウィンドウ高さ変更
　@winsize_set()　：画面サイズ固定
　@expand_exec()　：拡張シナリオ

@key_wait_p()
では『@set_chapter()』チャプター設定を説明します。
　@set_chapter(P1)：チャプター設定
　P1：チャプター名称(半角30文字まで)

@key_wait_p()
「チャプター」とはSAVE時に表示される短い説明文です。
チャプターがLOAD画面で確認できます。


@key_wait_p()
@stage(ロード画面1280.png)
これが「チャプター」ですね。
日付の下の文字列です。
チャプターを付ける事で、セーブデータの判別が分かりやすくなります。

@key_wait_p()
システムボタン無効設定
　@button_dis(P1ボタン種別,P2有効無効)
　P1:ボタン種別：ボタン名称　P2:有効無効：0 または 1　　(0:有効、1:無効)

　※ボタン種別：指定する機能ボタン名称　名称は以下の通り
　"SAVE"(保存ボタン)、"LOAD"(読み込みボタン)、"SKIP"(スキップボタン)
　"CONF"(コンフィグボタン)、"END"(終了ボタン)、"BACKLOG"(履歴ボタン)

@key_wait_p()
試しに、SAVEボタンを無効にします。
例：@button_dis(SAVE,1)

@key_wait_p()
@button_dis(SAVE,1)
「SAVE」ボタンが押せないですね。
※ポインタを合わせても反転しない状態です。

@key_wait_p()
では、SAVEボタンを有効に戻します。
例：@button_dis(SAVE,0)

@key_wait_p()
@button_dis(SAVE,0)
「SAVE」ボタンが有効に戻りましたね。


@key_wait_p()
　@msg_full(P1)：メッセージ表示固定
　P1: 表示種別　0:ウィンドウ表示　1:フルスクリーン
メッセージ表示の種別(ウィンドウ表示、フルスクリーン表示)をコマンドで指定します。

シナリオ中は「コンフィグ」では指定不可ですが、
このコマンドで変更できます。
試しにメッセージ表示を「フルスクリーン」にしてみましょう。

@key_wait_p()
@msg_full(1)
どうでしょう？　フルスクリーンになっていますね？
今度は「ウィンドウ表示」に戻します。


@key_wait_p()
@msg_full(0)
ウィンドウ表示になりましたね！
では次のコマンドです。


@key_wait_p()
　@change_msg_win_h(P1)：メッセージウィンドウ高さ変更
　P1: 高さ　(範囲：40〜画面高さ)　(デフォルト：200)
メッセージウィンドウの高さをコマンドで指定します。　最低値は「40」　最大値は「現在のゲーム画面高さ」です。

メッセージウィンドウを「100」に変更してみます。

@key_wait_p()
@change_msg_win_h(100)
どうでしょう？　メッセージウィンドウの高さが「100」になりました。
今度は「元の高さに(200)」に戻します。


@key_wait_p()
@change_msg_win_h(200)
これで元の高さに戻りましたね！
では次のコマンドです。

@key_wait_p()
　@winsize_set(P1)　画面サイズ固定
　　P1：画面サイズ　0:(800*600)　1:(1280*720)　2:(1920*1080)
画面サイズをコマンドで指定します。
シナリオ開始時に画面サイズを固定し、以後はその設定でシナリオを進めます。
(注意)当コマンドを使用する時はシナリオの開始時に設定して下さい。

@key_wait_p()
試しに画面サイズを「800*600」(縦800、横600)に変更してみましょう。

@key_wait_p()
@winsize_set(0)
画面サイズが「800*600」(縦800、横600)になりましたね。

@key_wait_p()
今度は画面サイズを「1280*720」(縦1280、横720)に変更してみましょう。

@key_wait_p()
@winsize_set(1)
画面サイズが「1280*720」(縦1280、横720)になりましたね。

@key_wait_p()
　拡張シナリオは色んな機能が追加できます。
　@expand_exec(P1)　：拡張シナリオ
　　P1：拡張シナリオEXEファイル名

　拡張シナリオは「expand」フォルダ下に有る追加EXEファイルです。

@key_wait_p()
　拡張シナリオにはパラメータで「共有メモリ」を設定する必要が有ります。
　共有メモリ番号は0〜999まで有ります。
※共有メモリに何を設定するかは、各拡張シナリオの説明を参照して下さい。

　共有メモリに値を設定するには、フラグ設定、加算、代入を使用して下さい。
　@set_flg(フラグ,設定値)：フラグ設定
　@add_flg(フラグ,設定値)：フラグ加算
　@copy_flg(コピー元フラグ,コピー先フラグ)：フラグ代入
　フラグに「ESP:XXX」とすると、フラグから共有メモリに設定出来ます。

@key_wait_p()
　フラグ設定で共有メモリ(0)に「2」を設定してみましょう。
例：@set_flg(ESP:0,2)

@key_wait_p()
@set_flg(ESP:0,2)
これで、共有メモリ(0)に「2」が設定されます。

@key_wait_p()
　次は共有メモリ(999)にフラグ(name#flg0)の値を設定してみましょう。
例：@set_flg(name#flg0,1),@copy_flg(name#flg0,ESP:999)

@key_wait_p()
@set_flg(name#flg0,1)
@copy_flg(name#flg0,ESP:999)
これで、共有メモリ(999)にフラグ(name#flg0)の値(1)が設定されます。

@key_wait_p()
では、試しに拡張シナリオ『クイズ』を起動させてみましょう。
　拡張シナリオは「expand」フォルダ下に有る追加EXEファイルです。

@key_wait_p()
@set_flg(ESP:0,0)
@set_flg(ESP:1,2)
@set_flg(ESP:2,1)
@set_flg(ESP:3,0)
@set_flg(ESP:4,0)
@@ @set_flg(ESP:4,2)
@@ ↑※背景画像を「1920」
@set_flg(ESP:5,0)
@set_flg(ESP:6,0)

@key_wait_p()
最初に、共有メモリに必要なデータを設定します。
※詳細は『拡張01クイズ説明.txt』を参照ください
例)ESP:0→出題大番号(0)、ESP:1→出題数(2)、ESP:2→ランダム出題(1)

@key_wait_p()
例) 拡張シナリオEXE(nh_拡張01クイズ_1280.exe)をシナリオ中に呼び出す
　※この後、拡張シナリオを実行し、1問クイズをして元のシナリオに戻ります。
　@expand_exec(nh_拡張01クイズ2.exe)


@key_wait_p()
@expand_exec(nh_拡張01クイズ2.exe)

@key_wait_p()
クイズを終えて、元のシナリオに戻りましたね。
今後、拡張シナリオが増えた場合は、同じようにシナリオを記述して下さい。


@key_wait_p()
システム系は以上です。
@dark(100)
@goto_label(選択2)
@@@@@@@@@@

*終了系
@key_wait_p()
@set_chapter(終了系)
@name(説明子)
ここで説明するコマンドは以下の通りです。
　@end()　：シナリオ終了
　パラメータ無し

シナリオ終了時に使用してください。
簡単ですね。

@key_wait_p()
これをコールする事でシナリオが終了します。
シナリオを終了させて「シナリオ表紙画面」に移行させる時は、必ず記述する
必要が有ります。

シナリオの最後や、シナリオ途中のバッドエンド等で使用して下さい。
※シナリオに終了が無く、ループする場合は必要ありません。

@key_wait_p()
ではコマンド説明を終了します。
頑張って自作シナリオに挑戦して下さい。
みなさん、さようなら〜

@end()
